Ringkasan

Gnuplot

# Author: Ika, 2013-07-24
set term svg size 800,600 enhanced font 'Times,12'
set output 'Second_Order_Taylor.svg'

set multiplot

set xlabel "x"
set ylabel "y"
set zlabel "z"
set xrange [-1.0:2.0]
set yrange [-0.5:2.0]
set zrange [-6.0:10.0]
set box
unset colorbox
#set view 65,45
set style fill solid 0.30 border

set cntrparam levels auto 20
set contour base
set isosamples 60,60
set samples 60,60
set pm3d
set hidd
unset key
set ticslevel 0
i = {0.0,1.0}

# Draw the surface of f(x,y) = e^x log(1+y)
set palette defined (-1 "blue", 1 "pink")
splot exp(x)*log(1+y)

# Draw the surface of f(x,y) = y+xy-y^2/2
set palette defined (-1 "red", 1 "orange")
splot y+x*y-y*y/2

# Draw the lines
unset cntrparam
unset contour
set isosamples 20,20
set samples 20,20
unset pm3d
unset hidd

# Draw the lines of f(x,y) = e^x log(1+y)
splot exp(x)*log(1+y) lt 2 lc rgb "black" lw 0.1

# Draw the lines of f(x,y) = y+xy-y^2/2
splot y+x*y-y*y/2 lt 2 lc rgb "black" lw 0.1

unset multiplot
set term x11
set output

Lisensi

Saya, pemilik hak cipta dari karya ini, dengan ini menerbitkan berkas ini di bawah ketentuan berikut:

Berkas ini dilisensikan dengan lisensi Creative Commons Atribusi-BerbagiSerupa 3.0 Tanpa Adaptasi

Anda diizinkan:

• untuk berbagi – untuk menyalin, mendistribusikan dan memindahkan karya ini
• untuk menggubah – untuk mengadaptasi karya ini

Berdasarkan ketentuan berikut:

• atribusi – Anda harus mencantumkan atribusi yang sesuai, memberikan pranala ke lisensi, dan memberi tahu bila ada perubahan. Anda dapat melakukannya melalui cara yang Anda inginkan, namun tidak menyatakan bahwa pemberi lisensi mendukung Anda atau penggunaan Anda.
• berbagi serupa – Apabila Anda menggubah, mengubah, atau membuat turunan dari materi ini, Anda harus menyebarluaskan kontribusi Anda di bawah lisensi yang sama seperti lisensi pada materi asli.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue